ENTREGUE AJUDA EU CARAI

[E D U A R D O]

Macro é pika e pá mas eu gostaria de deixar a parte de armazenamento mais rápida ( ela demora na hr de abrir os baus etc fica moscando)
e se n for pedir mt toda vez q ela vai guardar ela verifica todos baus do 1 ATÉ chegar no bau vazio, se alguma alma caridosa quiser modificar isso


$${
log(&9=============&6ExEspadas&9=============)
log(&dDEIXE SUAS &cESPADAS&d NO SLOT 1 até 9)
log(&9=============&6ExEspadas&9=============)
if(ex);
log(&6ExEspadas &4OFF);
unset(ex);
stop();
else;
log(&6ExEspadas &2ON);
set(ex);

&dir = %DIRECTION%;
#un=1;
#bau=1;
set(nf);

ifmatches(%&dir%,N);&dir=NORTH;endif;
ifmatches(%&dir%,S);&dir=SOUTH;endif;
ifmatches(%&dir%,E);&dir=EAST;endif;
ifmatches(%&dir%,W);&dir=WEST;endif;

do;


if(%DURABILITY%<70);

if(%#un%=9);log("&4[Macro] &6Matar mobs desativado.");
unset(ex);
stop();
endif;
log("&4[Macro] &6 Durabilidade baixa, espada trocada...");


look(0,90);
inc(#un);
inventoryup(1);
wait(500ms);
endif;


do(50);
look(%&dir%);
look(,-0);
wait(200ms);
key(attack);
loop;
if(nf);

wait(1);
gui(inventory);
wait(1);
getslotitem(35,#id,#stack);
if(%#stack%=0);
gui();
else;
do;
wait(1);}$$

$${if(%#bau%=1);}$$
/home bau1
$${endif;}$$
$${if(%#bau%=2);}$$
/home bau2
$${endif;}$$
$${if(%#bau%=3);}$$
/home bau3
$${endif;}$$
$${if(%#bau%=4);}$$
/home bau4
$${endif;}$$
$${if(%#bau%=5);}$$
/home bau5
$${endif;}$$
$${if(%#bau%=6);}$$
/home bau6
$${endif;}$$
$${if(%#bau%=7);}$$
/home bau7
$${endif;}$$
$${if(%#bau%=8);}$$
/home bau8
$${endif;}$$
$${if(%#bau%=9);}$$
/home bau9
$${endif;}$$

$${wait(15);
key(use);
wait(1);
for(#i,54,80);
slotclick(%#i%,l,true);
wait(30ms);
next;
wait(500ms);
getslotitem(53,#id,#stack);
wait(500ms);
if(%#stack%!=0);
inc(#bau);
endif;
if(%#bau%=9);
unset(nf);
log(&4[Macro] &6Baús cheios! Apenas matará mobs agora.);
gui();
else;
gui();
endif;
until(%#stack%=0);}$$
/home exespadas
$${endif;
endif;
loop;
endif;
}$$

 

[lomexicano]

dei um tapa

$${

#numero_de_baus = 9; //ultimo bau;


log("&9=============&6ExEspadas&9=============");
log("&dDEIXE SUAS &cESPADAS&d NO SLOT 1 até 9");
log("&9=============&6ExEspadas&9=============");
if(ex);
    log("&6ExEspadas &4OFF");
    unset(ex);
    stop();
else;
    log("&6ExEspadas &2ON");
    set(ex);
endif;

set(&dir,"%DIRECTION%");

if(#bau <= 0);
    #bau = 1;
endif;

prompt(#ans,"$$?","Deseja comecar de qual bau? vazio = %#bau%");
if(#ans >= 1);
    #bau = #ans;
elseif(#ans < 0);
    log("&6ExEspadas &4OFF");
    unset(ex);
    stop();
endif;   
#un=1;

set(nf);

if(&dir == "N");
    &dir="NORTH";
elseif(&dir == "S");
    &dir="SOUTH";
elseif(&dir == "E");
    &dir="EAST";
elseif(&dir == "W");
    &dir="WEST";
endif;

do();
    if(DURABILITY < 70);
        if(#un == 9);
            log("&4[Macro] &6Matar mobs desativado.");
            unset(ex);
            stop();
        endif;
        log("&4[Macro] &6 Durabilidade baixa, espada trocada...");

        look(0,90);
        inc(#un);
        inventoryup(1);
        wait(500ms);
    endif;
    do(50);
        look(%&dir%);
        look(,-0);
        wait(200ms);
        key(attack);
    loop;
    if(nf);
        wait(1);
        gui(inventory);
        wait(3t);
        getslotitem(35,#id,#stack);
        if(#stack == 0);
            gui();
        else;
            do;
                look(,90);
                wait(4t);
                if(#bau <= #numero_de_baus);
                    do(2);
                        echo("/home bau%#bau%");
                        do(30);
                            wait(3t);
                        until((HITID == 54)||(HITID == 146));
                    until((HITID == 54)||(HITID == 146));
                    gui();
                    wait(2t);
                    if((HITID == 54)||(HITID == 146));
                        key(use);
                        do(30);
                            wait(3t);
                        until(GUI == "GUICHEST");
                        wait(3t);
                        for(#i,54,80);
                            getslotitem(%#i%,#i,#j);
                            if(#j > 0);
                                slotclick(%#i%,l,true);
                            endif;
                        next;
                        getslotitem(53,#id,#stack);
                        if(#stack != 0);
                            inc(#bau);
                        endif;
                    endif;
                else;
                    unset(nf);
                    log("&4[Macro] &6Baús cheios! Apenas matará mobs agora.");
                    break;
                endif;
            until(#stack == 0);
            echo("/home exespadas");
        endif;
    endif;
loop;
}$$

 

[RIDaniela]

@lomexicano ... tu é top!
Sempre ajuda...