ENTREGUE [Propano] Pesca e vende blaze

Cake Blaze VIP
Apresento-lhes um macro de pescar e vender blaze rod. Segue o tutorial:

- Homes

• mobblaze -> home no mob de blaze
• venderblaze -> home virado para a placa de vender blaze rod

- Inventário

• Na hotbar deve haver uma ou mais varas de pesca em quaisquer slots.
• Recomenda-se iniciar o macro com pelo menos uma linha no inventário, apesar de não ser necessário.

- Trap

• Deve haver um bloco de ferro para a reparação abaixo do player.
• Deve haver um baú duplo atrás do player para a reposição de linhas.
• Recomenda-se colocar uma placa de compra de linha no baú.

- Funcionamento

• A cada fisgada, o inventário será verificado. Caso haja necessidade, as linhas serão rebastecidas ou a venda será acionada.
• Ao apertar F9 durante o funcionamento do macro, o macro será desligado.
• Ao apertar F8 durante o funcionamento do macro, o macro será pausado e abrirá o chat, continuando assim que o chat for fechado
• Ao reconectar, caso ainda não tenha resgatado o prêmio diário do calendário, o macro automaticamente resgatá-lo-á.

- Leia

• O código onchat não efetua o /login. Em breve postarei um macro que é colocado na onjoin que efetua o login.
• O macro foi feito para a 1.8, servidor Propano. Suporte não será oferecido caso usado em outro servidor.

- Códigos

• $$<CakeBlazeV.txt> -> pode ser colocado em qualquer tecla, mas o nome do arquivo deve ser este.
  
  Spoiler

  Código:

  $${
  // cakeblazev;
  #repair_dur=17;
  &home_venda="/home venderblaze";
  &home_mob="/home mobblaze";
  toggle(@cakeblazev);
  if(@cakeblazev);
      log("&6[Macro] &3CakeBlaze &a&oON");
      achievementget("CakeBlaze",blaze_rod);
      wait(1);
      achievementget("ON",cake);
      log("&6[Macro] &3");
      echo(%&home_mob%);
      do;until(%HIT%="ENTITY");
      wait(2);
      echo("/pvp off");
      do;gui(inventory);until(%GUI%="GUIINVENTORY");
      wait(1t);
      set(#yaw,%CARDINALYAW%);
      set(#pitch,%PITCH%);
      do;
          unsafe;
          do;
              look(%#yaw%,%#pitch%);
              pick(fishing_rod);
              key(use);
              if(KEY_F8);
                  log("&6[Macro] &3CakeBlaze &c&oPAUSE");
                  do;gui(chat);until(%GUI%="GUICHAT");
                  do;while(%GUI%="GUICHAT");
                  log("&6[Macro] &3CakeBlaze &a&oPLAY");
                  wait(1);
              endif;
              if(KEY_F9);
                  gui;
                  unset(@cakeblazev);
                  log("&6[Macro] &3CakeBlaze &c&oOFF");
                  stop("CAKEBLAZE");
                  stop;
              endif;
              if(%GUI%!="GUIINVENTORY");
                  do;gui(inventory);until(%GUI%="GUIINVENTORY");
              endif;
              set(#aircount,0);
              set(#stringcount,0);
              set(#rodcount,0);
              for(#i = 9 to 44);
                  getslotitem(%#i%,&id,#stack);
                  if(%&id%="air");
                      inc(#aircount);
                  endif;
                  if(%&id%="string");
                      inc(#stringcount);
                  endif;
                  if(%&id%="fishing_rod");
                      inc(#rodcount);
                  endif;
              next;
              if(%#aircount%<4);
                  wait(1t);
                  echo(%&home_venda%);
                  do;until(%HITID%="wall_sign");
                  wait(1);
                  echo("/menuloja off");
                  do;
                      gui();
                      wait(1t);
                      key(attack);
                      wait(7t);
                      gui(inventory);
                      wait(1t);
                      set(#aircount,0);
                      for(#i = 9 to 44);
                          getslotitem(%#i%,&id,#stack);
                          if(%&id%="air");
                              inc(#aircount);
                          endif;
                      next;
                  until(%#aircount%>3);
                  wait(1);
                  echo("/g &6varas incandescentes &fvendidas! &3#cakeblazev");
                  wait(1t);
                  echo(%&home_mob%);
                  do;until(%HIT%="ENTITY");
              endif;
              if(%#stringcount%<1);
                  looks(+180,0,1);
                  wait(5t);
                  key(use);
                  do;until(%GUI%="GUICHEST");
                  wait(3t);
                  for(#i = 0 to 53);
                      getslotitem(%#i%,&id,#stack);
                      if(%&id%="string");
                          slotclick(%#i%,LMOUSE,true);
                          break;
                      endif;
                  next;
                  looks(+180,0,1);
              endif;
              if(%DURABILITY%<%#repair_dur%);
                  unset(@cakerep);
                  gui;
                  do;
                      looks(,90,0.2);
                      key(use);
                  until(%DURABILITY%>40||@cakerep);
                  look(%#yaw%,%#pitch%,0.2);
                  key(use);
              endif;
          loop;
          endunsafe;
      loop;
  else;
      log("&6[Macro] &3CakeBlaze &c&oOFF");
      stop("CAKEBLAZE");
      stop;
  endif;
  }$$

• OnChat -> Deverá ser colocado no evento OnChat. Não tem um nome específico.
  
  Spoiler

  Código:

  $${
  ifmatches(%CHATCLEAN%,"^»Agora você está logado\. NUNCA.+");
      if(@cakeblazev);
          wait(2);
          unset(@cakeblazev);
          wait(3);
          echo("/g &freconectando &acakeblaze &3#cakeblazev");
          exec("CakeBlazeV.txt","CAKEBLAZE");
      endif;
  endif;
  ifmatches(%CHATCLEAN%,"^Isso já está com durabilidade cheia\.$");
      set(@cakerep);
  endif;
  ifmatches(%CHATCLEAN%,"^\[Calendário\] Você");
      echo("/calendario");
      do;until(%GUI%="GUICHEST");
      unsafe;
          for(#i,0,53);
              getslotitem(%#i%,&id,#stack,#data);
              if(%#data%=4);
                  slotclick(%#i%);
                  break;
              endif;
          next;
      endunsafe;
  endif;
  }$$
  

Peço que não retire as mensagens automáticas. É o jeito de divulgar o macro, já que está sendo passado gratuitamente a todos.

Bugs? Dúvidas? Sugestões? Mande aqui embaixo ou por MP!

 

Avisando aqui que esse macro, sabendo que o servidor Legacy vai ter diferenças de mecanismos, eu NÃO recomendo o uso dele antes de eu atualizar o macro.